0415f964150da23395f3b11e67b9a04427c16bc6
[sip-router] / docbook / dep.xsl
1 <?xml version='1.0'?>
2 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
3                                 version='1.0' xmlns:xi="http://www.w3.org/2001/XInclude">
4         <xsl:param name="output"/>
5
6         <!-- Write the output into a plaintext file which will be later included
7                  into the Makefile -->
8         <xsl:template match="/">
9                 <xsl:document href="{$output}" method="text" indent="no" 
10                                           omit-xml-declaration="yes">
11                         <xsl:value-of select="concat($output, ': ')"/>
12                         <xsl:apply-templates mode="subroot"/>
13                 </xsl:document>
14         </xsl:template>
15         
16         <!-- This template extract the name of the directory from a full pathname,
17              in other words it returns everything but the name of the file -->
18         <xsl:template name="dirname">
19                 <xsl:param name="filename"/>
20                 <xsl:if test="contains($filename, '/')">
21                         <xsl:value-of 
22                                 select="concat(substring-before($filename, '/'), '/')"/>
23                         <xsl:call-template name="dirname">
24                                 <xsl:with-param name="filename" 
25                                                                 select="substring-after($filename, '/')"/>
26                         </xsl:call-template>
27                 </xsl:if>
28         </xsl:template>
29
30         <!-- This template is used to add a directory preefix to a filename. The
31              prefix is only added if the filename is not absolute (i.e. it does
32              not start with a / and if the prefix is not an empty string -->
33         <xsl:template name="addprefix">
34                 <xsl:param name="prefix"/>
35                 <xsl:param name="filename"/>
36                 <xsl:if test="(string-length($prefix) > 0) and not(starts-with($filename, '/'))">
37                         <xsl:value-of select="$prefix"/>
38                 </xsl:if>
39                 <xsl:value-of select="$filename"/>
40         </xsl:template>
41         
42         <!-- This template processes xi:include directives that include other XML
43              documents. First the template outputs the name of the file being
44              included and then the template traverses the included file
45              recursively, searching fro other dependencies in that file.  The
46              template passes the parameter prefix to other templates with its
47              value set to the directory name of the file being included. This
48              ensures that paths to all dependencies are relative to the main
49              file. -->
50         <xsl:template match='xi:include' mode="subroot">
51                 <xsl:param name="prefix"/>
52
53                 <!-- Add the prefix to the name of the file being included and store
54                      the result in variable fullpath -->
55                 <xsl:variable name="fullpath">
56                         <xsl:call-template name="addprefix">
57                                 <xsl:with-param name="prefix" select="$prefix"/>
58                                 <xsl:with-param name="filename" select="@href"/>
59                         </xsl:call-template>
60                 </xsl:variable>
61
62                 <!-- First of all, output the name of the file being included, with
63                      proper prefix so that the resulting dependency is relative to the
64                      top-most file being processed, not the file we are are processing
65                      in this step. -->
66                 <xsl:value-of select="concat($fullpath, ' ')"/>
67
68                 <!-- Traverse the file being included and search for more depencencies
69                      in that file and other files included from there. -->
70                 <xsl:apply-templates select="document(@href)" mode="subroot">
71                         <!-- Extract the directory name from $fullpath and set it as a new
72                              value of the prefix parameter before calling other templates.
73                         -->
74                         <xsl:with-param name="prefix">
75                                 <xsl:call-template name="dirname">
76                                         <xsl:with-param name="filename" select="$fullpath"/>
77                                 </xsl:call-template>
78                         </xsl:with-param>
79
80                         <!-- Process the included file recursively -->
81                 </xsl:apply-templates>
82         </xsl:template>
83         
84         <!-- This template processes files included with xi:include that are not
85              XML files, such files will only be output as dependencies and will be
86              not traversed recursively. -->
87         <xsl:template match='xi:include[@parse="text"]' mode="subroot">
88                 <xsl:param name="prefix"/>
89                 <xsl:call-template name="addprefix">
90                         <xsl:with-param name="prefix" select="$prefix"/>
91                         <xsl:with-param name="filename" select="@href"/>
92                 </xsl:call-template>
93                 <xsl:text> </xsl:text>
94         </xsl:template>
95         
96         <!-- This template processes mediaobjects (such as images) included in
97              docbook. -->
98         <xsl:template match="graphic|imagedata|inlinemediaobject|textdata" 
99                                   mode="subroot">
100                 <xsl:param name="prefix"/>
101                 <xsl:call-template name="addprefix">
102                         <xsl:with-param name="prefix" select="$prefix"/>
103                         <xsl:with-param name="filename" select="@fileref"/>
104                 </xsl:call-template>
105                 <xsl:text> </xsl:text>
106         </xsl:template>
107         
108         <!-- Supress all other output -->
109         <xsl:template match="text()|@*" mode="subroot"/>
110 </xsl:stylesheet>